VBA To Handle White Cell Fill Colors

VBA Target Cell Interior Fill Color of White

What This VBA Code Does

If you are a formatting nut like me, you will most likely appreciate an issue I face all too often. Imagine you are taking over someone else's spreadsheet who doesn't have a care in the world for formatting and organization and also doesn't know that you can get a solid white background for your spreadsheet by simply turning off the grid lines (View >> Show >> Gridlines). In an effort to add some order to this disaster of a spreadsheet, you are left going through the tabs and searching for white filled cells and removing their cell fill or searching for unfilled cells and making them white. Not a real value-add of your time....

Have no fear, I have created some code that will search through all the cells in your selection and fill them with a white color while ignoring cells that are already colored something other than white. The code acts as a toggle between converting cells to white and removing the background of white filled cells. Enjoy!

VBA Code:

Sub WhiteFill_Toggle()
'PURPOSE: Change empty cell fill colors to white based on selection (Toggle)
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim rng As Range
Dim cell As Range
Dim GatherRange As Range

'Test for Empty Filled Cells in User Selection
  For Each cell In Selection.Cells
    If cell.Interior.ColorIndex = xlNone Then
      If GatherRange Is Nothing Then
        Set GatherRange = cell
      Else
        Set GatherRange = Union(GatherRange, cell)
      End If
    End If
  Next cell

'Were any empty filled cells found?
  If Not GatherRange Is Nothing Then
    'Whiteout all applicable cells
      GatherRange.Interior.Color = RGB(255, 255, 255)
  Else
    'Test for White Fills
      For Each cell In Selection.Cells
        If cell.Interior.Color = RGB(255, 255, 255) Then
          If GatherRange Is Nothing Then
            Set GatherRange = cell
          Else
            Set GatherRange = Union(GatherRange, cell)
          End If
        End If
      Next cell
      
    'Remove White Fills
      If Not GatherRange Is Nothing Then
        GatherRange.Interior.ColorIndex = xlNone
      End If
    End If
  
End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris
Founder, TheSpreadsheetGuru.com