VBA Macro Code To Create Monthly Folders Inside A Parent Folder

VBA Macro Code To Create Monthly Folders Inside A Parent Folder

What This VBA Code Does

I often find myself needing to set up monthly folders for routine reports. Instead of manually creating and renaming all these new folders, you can use VBA code to automatically set up the folder structure for you! 

There are endless possibilities conceptually with this macro, but for my personal needs, I needed a structure that looked like this:

New Monthly Folder Structure Created by VBA Macro Code

Below is the VBA code you can use to create a folder structure exactly like what is shown above within whatever parent folder you choose. Enjoy!

Sub CreateMonthlyFolders()
'PURPOSE: Create monthly subfolders within a folder
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim ParentFolder As String
Dim SubFolder As String
Dim NewPath As String
Dim FldrPicker As FileDialog
Dim Skip As Boolean

'Retrieve Target Folder Path From User
  
  'Launch Folder Dialog Box
    Set FldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
    
  'Record User's Selection
    With FldrPicker
      .Title = "Select A Target Folder"
      .AllowMultiSelect = False
        If .Show <> -1 Then Skip = True
        If Not Skip Then ParentFolder = .SelectedItems(1)
    End With

  'In Case User Cancels
    If ParentFolder = "" Then Exit Sub

'Loop Through Each Month
  For x = 1 To 12
  
    'Create new folder path
      SubFolder = Format(x, "00. ") & MonthName(x, False)
      NewPath = ParentFolder & "\" & SubFolder
    
    'Check if folder already exists
      If Dir(NewPath, vbDirectory) = "" Then
        
        'Create new subfolder
          Shell ("cmd /c mkdir """ & NewPath & """")
      
      End If
  
  Next x
  
'Report Results
  MsgBox "12 monthly folders were created in the target folder."

End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

~ Chris