VBA Code To Change All Shape & Chart Placement Properties

VBA Macro Shape & Chart Object Placement Property

What This VBA Macro Does

Move and Size with Cells, Move But Don't Size with Cells, Don't mover or size with cells

I deal with shapes and charts on a daily basis and one of my (many) pet peeves is needing to resize column widths and screwing up the size of my shapes and charts. I'm going to share with you a few VBA macros that will allow you to change the Placement property of all the shapes and charts on your ActiveSheet with the click of the button. The last VBA snippet is the one I use personally almost daily. Enjoy!

Change Every Shape & Chart To A Specific Placement

In this first macro, you can write which specific Placement property you want every shape and graph to change to. Your options are xlMove, xlFreeFloating, or xlMoveAndSize.

Sub Shapes_ResizeMoveProperty()
'PURPOSE: Change All Shapes Object Positioning Property
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim shp As Shape
Dim cht As ChartObject
Dim PropertyOption As Integer

'Options: xlFreeFloating, xlMoveAndSize, xlMove
  PropertyOption = xlMove

'Loop Through Shapes & Controls
  For Each shp In ActiveSheet.Shapes
    shp.Placement = PropertyOption
  Next shp

'Loop Through Charts
  For Each cht In ActiveSheet.ChartObjects
    cht.Placement = PropertyOption
  Next cht

End Sub

Ask The User To Decide The Shape & Chart Placement

In this next VBA macro, your code will ask you which Placement type you want to apply to all the shapes and charts.

Sub Shapes_ResizeMoveProperty_Input()
'PURPOSE: Change All Shapes Object Placement Property (User Input)
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim shp As Shape
Dim cht As ChartObject
Dim PropertyOption As Integer

'Retrieve Input from User
  PropertyOption = Application.InputBox("Change Everything To What Placement Property?" & _
   "(Must be 1, 2, or 3)" & vbCr & vbCr & "   [1] Move and Size with Cells" & vbCr & _
   "   [2] Move but Don't Size with Cells" & vbCr & "   [3] Don't Move or Size with Cells" & _
   vbCr & " ", Type:=1, Title:="Placement Property For All")

    'Handle If User Cancels
      If PropertyOption = 0 Then Exit Sub

'Loop Through Shapes & Controls
  For Each shp In ActiveSheet.Shapes
    shp.Placement = PropertyOption
  Next shp

'Loop Through Charts
  For Each cht In ActiveSheet.ChartObjects
    cht.Placement = PropertyOption
  Next cht

End Sub

Cycle Through The 3 Different Placement Options

This is the VBA macro I personally use where I can keep running the code until it lands on the specific Placement option I am wanting. This VBA code is currently sitting in my Quick Access Toolbar and I use it all the time!

Sub Shapes_ResizeMoveProperty_Cycle()
'PURPOSE: Change All Shapes Object Placement Property (Cycle)
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault
'ENUMERATIONS: xlMoveAndSize = 1, xlMove = 2, xlFreeFloating = 3

Dim shp As Shape
Dim cht As ChartObject
Dim PropertyOption As Integer

'Determine which Placement to Apply
  For Each shp In ActiveSheet.Shapes
    PropertyOption = Choose(shp.Placement, 2, 3, 1)
    GoTo PlacementChoosen
  Next shp
  
  For Each cht In ActiveSheet.ChartObjects
    PropertyOption = Choose(cht.Placement, 2, 3, 1)
    GoTo PlacementChoosen
  Next cht
  
  'Nothing Found
    MsgBox "No objects were found to adjust the placement property"
    Exit Sub

PlacementChoosen:

'Handle If User Cancels
  If PropertyOption = 0 Then Exit Sub

'Loop Through Shapes & Controls
  For Each shp In ActiveSheet.Shapes
    shp.Placement = PropertyOption
  Next shp

'Loop Through Charts
  For Each cht In ActiveSheet.ChartObjects
    cht.Placement = PropertyOption
  Next cht

'Report action taken to user
  Select Case PropertyOption
    Case 1: MsgBox "All Charts & Shapes set to: " & Chr(34) & "Move and Size with Cells" & Chr(34)
    Case 2: MsgBox "All Charts & Shapes set to: " & Chr(34) & "Move but Don't Size with Cells" & Chr(34)
    Case 3: MsgBox "All Charts & Shapes set to: " & Chr(34) & "Don't Move or Size with Cells" & Chr(34)
  End Select
  
End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

~ Chris