VBA To Only Change Selection's Border Color

VBA Macro Code To Change Cell Border Color

What This VBA Code Does

Let’s face it, it’s a real pain to change the colors of borders….especially if they have already been added throughout your spreadsheet. Because of this, I created a VBA macro that takes a range of selected cells and allows the user to change to color of all borders within the selection. I am including two versions of the VBA code: one with a prompt to pick a color at run-time and a version that changes the border to a pre-determined color.

VBA Code With Color Prompt:

Sub ChangeBorderColor()
'PURPOSE: Change Border Colors without affecting thickness/styles
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim cell As Range
Dim DesiredColor As Long

'Ensure Range is Selected
  If TypeName(Selection) <> "Range" Then Exit Sub

'Launch Color Palette & Test if OK Button was clicked
  If Application.Dialogs(xlDialogEditColor).Show(11, 0, 0, 0) = True Then
    DesiredColor = ActiveWorkbook.Colors(11)
  Else
    Exit Sub 'User canceled
  End If

'Loop Through each cell in selection and change border color (if applicable)
  For Each cell In Selection.Cells
    If cell.Borders(xlEdgeTop).LineStyle <> xlNone Then cell.Borders(xlEdgeTop).Color = DesiredColor
    If cell.Borders(xlEdgeBottom).LineStyle <> xlNone Then cell.Borders(xlEdgeBottom).Color = DesiredColor
    If cell.Borders(xlEdgeLeft).LineStyle <> xlNone Then cell.Borders(xlEdgeLeft).Color = DesiredColor
    If cell.Borders(xlEdgeRight).LineStyle <> xlNone Then cell.Borders(xlEdgeRight).Color = DesiredColor
    If cell.Borders(xlDiagonalDown).LineStyle <> xlNone Then cell.Borders(xlDiagonalDown).Color = DesiredColor
    If cell.Borders(xlDiagonalUp).LineStyle <> xlNone Then cell.Borders(xlDiagonalUp).Color = DesiredColor
  Next cell

End Sub

 

VBA Code Without Color Prompt:

Sub ChangeBorderColor()
'PURPOSE: Change Border Colors without affecting thickness/styles
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim cell As Range
Dim DesiredColor As Long

'Color To Change Borders To
  DesiredColor = RGB(16, 124, 65)

'Ensure Range is Selected
  If TypeName(Selection) <> "Range" Then Exit Sub

'Loop Through each cell in selection and change border color (if applicable)
  For Each cell In Selection.Cells
    If cell.Borders(xlEdgeTop).LineStyle <> xlNone Then cell.Borders(xlEdgeTop).Color = DesiredColor
    If cell.Borders(xlEdgeBottom).LineStyle <> xlNone Then cell.Borders(xlEdgeBottom).Color = DesiredColor
    If cell.Borders(xlEdgeLeft).LineStyle <> xlNone Then cell.Borders(xlEdgeLeft).Color = DesiredColor
    If cell.Borders(xlEdgeRight).LineStyle <> xlNone Then cell.Borders(xlEdgeRight).Color = DesiredColor
    If cell.Borders(xlDiagonalDown).LineStyle <> xlNone Then cell.Borders(xlDiagonalDown).Color = DesiredColor
    If cell.Borders(xlDiagonalUp).LineStyle <> xlNone Then cell.Borders(xlDiagonalUp).Color = DesiredColor
  Next cell

End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris
Founder, TheSpreadsheetGuru.com