Remove A Specific Fill Color From Your Spreadsheet

Remove A Specific Fill Color From Your Spreadsheet

What This VBA Code Does

This VBA macro code will allow you to remove a specific fill color from your entire worksheet without affecting any other fill color on the tab. In order to properly do this, you will need to determine the RGB color code for your desired color that will be removed.

You can determine the RGB color code of a cell by:

  1. Right-clicking on the cell with the fill color you want
  2. Selecting Format Cells
  3. In the Format Cells dialog box, go to the Fill tab and click the More Colors... button
  4. Then go to the Custom tab within the Colors dialog box and you will see the "Red", "Green", "Blue" values for the cell's current fill color

Sub RemoveSpecificColorFill()
'PURPOSE: Remove a specific fill color from the spreadsheet
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim cell As Range

'Turn off ScreenUpdating (speeds up code)
  Application.ScreenUpdating = False

'Loop through each cell in the ActiveSheet
  For Each cell In ActiveSheet.UsedRange
    
    'Check for a specific fill color
      If cell.Interior.Color = RGB(219, 229, 241) Then
        
        'Remove Fill Color
          cell.Interior.Color = xlNone
      
      End If
  
  Next cell

End Sub

A More Dynamic Option

For a more dynamic solution where you don't have to mess around with RGB color codes, you can use the below macro code. It requires you to first select a cell with the fill color you wish to target. Then after you run the code, it will select all cells on the sheet contain that cell's fill color. Afterwards, you can manually change the selected cell's fill color to whatever you want!

Sub SelectSpecificColorFill()
'PURPOSE: Select all cells with a specific fill color from the spreadsheet
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim cell As Range
Dim CellColor As Long
Dim rng As Range

'Turn off ScreenUpdating (speeds up code)
  Application.ScreenUpdating = False

'Store the cell the user selected
  Set rng = ActiveCell

'Get color of selected cell
  CellColor = rng.Interior.Color

'Loop through each cell in the ActiveSheet
  For Each cell In ActiveSheet.UsedRange
    
    'Check for a specific fill color
      If cell.Interior.Color = CellColor Then
        
        'Add to selection range
          Set rng = Union(rng, cell)
      
      End If
  
  Next cell
  
'Select all cells with the specified color
  rng.Select

End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris "Macro" Newman :)