How To Determine Hex Color Codes For VBA Userforms

How To Determine Hex Color Codes For VBA Userforms

What This VBA Code Does

If you have ever formatted VBA userforms, you’ve most likely noticed that the color codes use a weird syntax. An example might look like this: &H8000000F&. So how are we supposed to interpret this?

Understanding the Visual Basic Userform Color Codes

Looking at the above breakdown of the syntax we can more clearly understand how to construct a color code to bring in custom colors into our userform. One thing that trips up most people is the typical RGB colors are used in reverse (ie BGR).

One thing I will explain in a little more detail is the third part of the syntax where you need to either use “80” or “00”. The 80 will indicate predetermined constant colors within Visual Basic. These colors are all named and are the ones you can select from in the drop downs within the Properties Pane (ie Scrollbars, Desktop, Windows Background, etc…). If you are wanting to use a custom color code, you will want to replace the 80 with a 00.

VBA Code:

Since I am such a nice guy, I’ve gone ahead and put together some VBA code that you can use to figure out the color code to use by reading any selected cell’s fill color. Simply select some cells filled with your desired colors and run the below code. The color code for each cell will be displayed next to each cell you had selected.

Sub DetermineVisualBasicHexColor()
'PURPOSE: Display Visual Basic HEX Color Code next to each cell's Fill Color

Dim cell As Range
Dim FillHexColor As String

'Ensure a cell range is selected
  If TypeName(Selection) <> "Range" Then Exit Sub

'Loop through each cell in selection
  For Each cell In Selection.Cells
  
    'Ensure cell has a fill color
      If cell.Interior.ColorIndex <> xlNone Then
      
        'Get Hex values (values come through in reverse of what we need)
          FillHexColor = Right("000000" & Hex(cell.Interior.Color), 6)
        
        'Convert to the Visual Basic Userform Color Code Format
          cell.Offset(0, 1).Value = "&H00" & FillHexColor & "&"
          
      End If
      
  Next cell

'Select just the ActiveCell
  ActiveCell.Select

End Sub

Example:

The below image shows how the above VBA macro places the HEX color code beside each colored cell. You can then proceed to copy the desired color code and paste it into the applicable userform property field within the Visual Basic Editor.

Excel Userform Custom Color Code Example

Alternative Method

There was also another method proposed in the comments section of this article to determine the HEX color code using the RGB function. Here are the steps:

  1. Open the Immediate Window (ctrl + g) inside the Visual Basic Editor

  2. Type “?” and the RGB function with the RGB color you would like to convert.

    • Example: ?RGB(237,125,39)

  3. Hit your Enter key

  4. Copy the numerical code that appears after you hit the Enter key

  5. Paste that code as the color code for your desired userform color and hit your Enter key again

After following those steps, you should see the proper HEX code appear and your desired color show up on your userform.

Convert RGB Color To HEX with VBA

Further Resources:

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris
Founder, TheSpreadsheetGuru.com