Ask If User Wants To Save File Before Executing VBA Macro

Ask to Save File befor running VBA Macro Code

What This VBA Code Does

In Excel and Microsoft Word you cannot undo a macro once it has run. Sometimes we create code that does so much that it is impossible to reverse. As a safeguard, it might be wise to make the user pause for a second and determine whether he/she should save their file before running the VBA code. Let's see how we can do this.

In Microsoft Excel

Sub AskToSave()
'PURPOSE: Ask user if he would like to save before executing rest of code
'SOURCE: www.TheSpreadsheetGuru.com

Dim UserAnswer As Long
Dim SaveAsChoice As Long
Dim SavePath As String
Dim FileExt As String
Dim ExtNumber As Long

'Ask user if he wants to save before executing
  If ThisWorkbook.Saved = False Then
    UserAnswer = MsgBox("Would you like to save before running?", vbYesNoCancel, "Save?")
      
      If UserAnswer = vbCancel Then Exit Sub 'User clicked cancel button
      
      If UserAnswer = vbYes Then
        If ThisWorkbook.Path <> "" Then
          'Need to SaveAs
            SaveAsChoice = Application.FileDialog(msoFileDialogSaveAs).Show
            If SaveAsChoice <> 0 Then
              SavePath = Application.FileDialog(msoFileDialogSaveAs).SelectedItems(1)
              
                'Determine File Extension Number for SaveAs
                  FileExt = Right(SavePath, Len(SavePath) - InStrRev(SavePath, "."))
                
                'Get File Format Number (based off of extension)
                    Select Case FileExt
                      Case "xlsx": ExtNumber = 51
                      Case "xlsm": ExtNumber = 52
                      Case "xlsb": ExtNumber = 50
                      Case "xls": ExtNumber = 56
                    End Select
              
              ThisWorkbook.SaveAs SavePath, ExtNumber
            Else
              Exit Sub 'User clicked cancel button
            End If
        Else
          ThisWorkbook.Save
        End If
      End If
  End If

  'Insert the rest of you code here...

End Sub

In Microsoft Word

Sub AskToSave()
'PURPOSE: Ask user if he would like to save before executing rest of code
'SOURCE: www.TheSpreadsheetGuru.com

Dim UserAnswer As Long
Dim SaveAsChoice As Long
Dim SavePath As String
Dim FileExt As String
Dim ExtNumber As Long

'Ask user if he wants to save before executing
  If ThisDocument.Saved = False Then
    UserAnswer = MsgBox("Would you like to save before running?", vbYesNoCancel, "Save?")
      
      If UserAnswer = vbCancel Then Exit Sub 'User clicked cancel button
      
      If UserAnswer = vbYes Then
        If ThisDocument.Path <> "" Then
          'Need to SaveAs
            SaveAsChoice = Application.FileDialog(msoFileDialogSaveAs).Show
            If SaveAsChoice <> 0 Then
              SavePath = Application.FileDialog(msoFileDialogSaveAs).SelectedItems(1)
              
                'Determine File Extension Number for SaveAs
                  FileExt = Right(SavePath, Len(SavePath) - InStrRev(SavePath, "."))
                
                'Get File Format Number (based off of extension)
                    Select Case FileExt
                      Case "docx": ExtNumber = 12
                      Case "doc": ExtNumber = 0
                      Case "docm": ExtNumber = 13
                    End Select
              
              ThisDocument.SaveAs SavePath, ExtNumber
            Else
              Exit Sub 'User clicked cancel button
            End If
        Else
          ThisDocument.Save
        End If
      End If
  End If

  'Insert the rest of you code here...

End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris "Macro" Newman :)