Add New Worksheet Tabs With A Range Of Sheet Names

VBA Macro Code Create New worksheets with Table Cells

What This VBA Code Does

This VBA macro will take a list of sheet names within an Excel table and create a new sheet for any worksheet that does not currently exist (renaming the new worksheet as well). This macro uses a function I created call SheetExists, which determines if the sheet already exists in the active workbook. Make sure to include both pieces of code in your VBA project before trying to execute. Enjoy!

A special thanks to a friend from 'Down Under' for the inspiration to write this code

Sub CreateSheetsFromList()
'PURPOSE: Create new worksheets from a list of names within a table

Dim NewSheet As Worksheet
Dim x As Integer
Dim tbl As ListObject
Dim cell As Range

'Opitimize Code
  Application.ScreenUpdating = False

'Store table in a variable
  Set tbl = Worksheets("Sheet1").ListObjects("Table1")

'Create a new worksheet for every name inside the table
  For Each cell In tbl.DataBodyRange.Cells
    If SheetExists(cell.Value) = False And cell.Value <> "" Then
      Set NewSheet = Sheets.Add(after:=Sheets(Sheets.Count))
      NewSheet.Name = cell.Value
    End If
  Next cell

'Opitimize Code
  Application.ScreenUpdating = True
End Sub

Function To Test If Tab Already Exists

To go along with the subroutine above, I used a function (shown below) to test if the worksheet name already exists. You will need to paste this VBA function below the CreateSheetsFromList macro.

Function SheetExists(SheetName As String) As Boolean
'PURPOSE: Determine is a worksheet exists in the ActiveWorkbook

Dim sht As Worksheet

'Test if sheet can be found
  On Error Resume Next
    Set sht = ActiveWorkbook.Worksheets(SheetName)
  On Error GoTo 0

'Determine function result
  If Not sht Is Nothing Then SheetExists = True

'Clear Memory
  Set sht = Nothing

End Function

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris "Macro" Newman :)