Aligning Shape Objects With VBA Code

Aligning Shape Objects With VBA Macro Code

What This VBA Does

I could not find any way to call the Excel-based alignment actions with VBA, so I set out to create some mathematical equations to get your shapes perfectly aligned.  The below code shows how you can use VBA to align two specific shapes in 6 different ways.

Sub AlignTwoShapes()
'PURPOSE: Align Two Shapes on the Active Spreadsheet
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim Shp1 As Shape
Dim Shp2 As Shape

'Shape To Align with (Stays put)
  Set Shp1 = ActiveSheet.Shapes("Shape 1")
  
'Shape That Gets Aligned (moves)
  Set Shp2 = ActiveSheet.Shapes("Shape 2")

    'Align Left
      Shp2.Left = Shp1.Left
      
    'Align Right
      Shp2.Left = Shp1.Left + (Shp1.Width - Shp2.Width)
      
    'Align Top
      Shp2.Top = Shp1.Top
      
    'Align Bottom
      Shp2.Top = Shp1.Top + (Shp1.Height - Shp2.Height)
    
    'Align Middle (Horizontal Center)
      Shp2.Top = Shp1.Top + ((Shp1.Height - Shp2.Height) / 2)
    
    'Align Center (Vertical Center)
      Shp2.Left = Shp1.Left + ((Shp1.Width - Shp2.Width) / 2)

End Sub

Aligning Based Off Of A User Selection

I wanted to take this concept a step further and run an alignment action affecting only the shapes that are selected.  The below macro code aligns all the other shapes in the selection with the first shape that was selected by the user.  Again you can pick which alignment or alignment combination you want by deleting (or commenting out) the unwanted actions in the code.

Sub AlignMultipleShapes()
'PURPOSE: Align each shape in user's selection (first shape selected stays put)
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim Shp1 As Shape
Dim Shp2 As Shape
Dim x As Integer
Dim y As Integer

'Count How Many Shapes Are Selected
  x = Windows(1).Selection.ShapeRange.Count

'Loop Through each selected Shape (align with first selected)
  For y = 1 To x
    If Shp1 Is Nothing Then
      Set Shp1 = Windows(1).Selection.ShapeRange(y)
    Else
      Set Shp2 = Windows(1).Selection.ShapeRange(y)
        
        'Align Left
          Shp2.Left = Shp1.Left
              
        'Align Right
          Shp2.Left = Shp1.Left + (Shp1.Width - Shp2.Width)
  
        'Align Top
          Shp2.Top = Shp1.Top
  
        'Align Bottom
          Shp2.Top = Shp1.Top + (Shp1.Height - Shp2.Height)
  
        'Align Middle (Horizontal Center)
          Shp2.Top = Shp1.Top + ((Shp1.Height - Shp2.Height) / 2)
  
        'Align Center (Vertical Center)
          Shp2.Left = Shp1.Left + ((Shp1.Width - Shp2.Width) / 2)
          
      End If
  Next y

End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris "Macro" Newman :)