VBA Code To Remove Duplicate Cell Values Or Entire Rows

VBA Excel Macro Remove Duplicate Values Entire Rows

What This VBA Code Does

Sometimes when you are cleaning up all the cobwebs of your data, you discover your spreadsheet possesses a bunch of duplicate values.  Yes, you could convert your data into a Table and then use the Remove Duplicates feature within the Table Options ribbon menu, but who wants to waste the effort with all those clicks? Here are a couple VBA macros you can add to your Personal macros to speed up this process and rid your data of duplicate values.

Remove Duplicate Cell Values Within A Range Selection

Sub RemoveDuplicatesCells()
'PURPOSE: Remove duplicate cell values within a selected cell range
'SOURCE: www.TheSpreadsheetGuru.com

Dim rng As Range
Dim x As Integer

'Optimize code execution speed
  Application.ScreenUpdating = False

'Determine range to look at from user's selection
  On Error GoTo InvalidSelection
    Set rng = Selection
  On Error GoTo 0

'Determine if multiple columns have been selected
  If rng.Columns.Count > 1 Then
    On Error GoTo InputCancel
      x = InputBox("Multiple columns were detected in your selection. " & _
        "Which column should I look at? (Number only!)", "Multiple Columns Found!", 1)
    On Error GoTo 0
  Else
    x = 1
  End If

'Optimize code execution speed
  Application.Calculation = xlCalculationManual
  
'Remove entire row
  rng.RemoveDuplicates Columns:=x

'Change calculation setting to Automatic
  Application.Calculation = xlCalculationAutomatic
  
Exit Sub

'ERROR HANDLING
InvalidSelection:
  MsgBox "You selection is not valid", vbInformation
  Exit Sub

InputCancel:

End Sub

Remove Entire Rows of Duplicate Values

Sub RemoveDuplicatesCells_EntireRow()
'PURPOSE: Remove the entire row of duplicate cell values within a selected cell range
'SOURCE: www.TheSpreadsheetGuru.com

Dim rng As Range
Dim x As Integer

'Optimize code execution speed
  Application.ScreenUpdating = False

'Determine range to look at from user's selection
  On Error GoTo InvalidSelection
    Set rng = Selection
  On Error GoTo 0

'Ask user which column to look at when analyzing duplicates
  On Error GoTo InputCancel
    x = InputBox("Which column should I look at? (Number only!)", _
      "Select A Column", 1)
  On Error GoTo 0

'Optimize code execution speed
  Application.Calculation = xlCalculationManual

'Remove entire row if duplicate is found
  rng.EntireRow.RemoveDuplicates Columns:=x

'Change calculation setting to Automatic
  Application.Calculation = xlCalculationAutomatic
  
Exit Sub

'ERROR HANDLING
InvalidSelection:
  MsgBox "You selection is not valid", vbInformation
  Exit Sub

InputCancel:

End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris "Macro" Newman :)