Selecting Non-Blank Cells In An Excel Column

Learn VBA Macros From Microsoft Excel Code Vault Snippets

What This VBA Code Does

The below VBA macro code will allow you to select only the cells in a stated column range that contain values or formulas.  Note that if a formula outputs a blank value (ie "") then it WILL NOT BE included in the selection, even thought the cell contains a formula.  Scroll down to the next VBA snippet to include such formulas.

Sub SelectNonBlanks()

'PURPOSE: Selects only cells with values or formulas that do NOT output blank values (ie ="" or +"")
'SOURCE: www.TheSpreadsheetGuru.com

Dim rng As Range

Set rng = Range("A1:A10")

'Selecting only hardcoded data
  rng.SpecialCells(xlCellTypeConstants).Select

'Selecting only formulas
  rng.SpecialCells(xlCellTypeFormulas).Select
  
'Selecting hardcoded data and formulas
  Union(rng.SpecialCells(xlCellTypeConstants), _
    rng.SpecialCells(xlCellTypeFormulas)).Select

End Sub

What This VBA Code Does

The below VBA macro code will allow you to select only the cells in a stated column range that contain values or formulas.  Note that if a formula outputs a blank value (ie "") then it WILL BE included in the selection, even thought the cell contains a formula.  

A special thanks to MrExcel MVP Rick Rothstein for showing me how to code the below subroutine.

Sub SelectNonBlankCells_ExcludingDoubleQuotes()

'PURPOSE: Selects only cells with values or formulas and excludes blank values (ie ="" or +"")
'AUTHOR: Rick Rothstein (MrExcel MVP)
'SOURCE: www.TheSpreadsheetGuru.com

Dim rng As Range
Dim UnusedColumn As Range
  
Set rng = Range("A1:A100")

'Find a column with nothing in it
  Set UnusedColumn = Cells.Find("*", , xlFormulas, , xlByColumns, xlPrevious).EntireColumn.Offset(0, 1)

'Create temporary calculation column to determine which cells to select (marked by an X)
  Intersect(rng.EntireRow, UnusedColumn) = Evaluate("IF(" & rng.Address & "="""","""",""X"")")

'Make Selection
  Intersect(UnusedColumn.SpecialCells(xlConstants).EntireRow, rng.EntireColumn).Select

'Remove Temporary Blank Caluclations
  UnusedColumn.Clear
  
End Sub

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to getting quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Chris "Macro" Newman :)