×

Format VBA Code Inside A Microsoft Word Document

By Chris Newman •  Updated: 06/23/15 •  5 min read
Format Word Document Text Similar to Visual Basic Editor

What This VBA Code Does

I have found over the years that organizing your past VBA code snippets can really save you time while working on future projects. I think the main reason is due to the fact that we tend understand our own coding style much better than others. Below is some VBA code I wrote a while back to format my copied code inside a Word document to match how it would appear while viewing the code inside the Visual Basic Editor.

Sub VBA_TextFormat()
'PURPOSE: Format selected text similar to VBE appearance
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim MySelection As Range
Dim MySelection_Limit As Range
Dim BlueArray As Variant

BlueArray = Array("End Sub", "End If", "For ", "In ", "Do While", "Sub ", "Set ", "As ", _
  "As Single", "Dim ", "With ", "End With", "If ", "Else ", "ElseIf ", "On Error GoTo ", _
  "On Error GoTo 0", "Sub ", "Exit Sub", "For Each ", "Next ", "Private Sub ", " True", _
  " False", " To ", " LBound", " UBound", "Wend", "While ", " Then", "Preserve ")

Set MySelection = Selection.Range
Set MySelection_Limit = MySelection.Duplicate

'Adjust font type and font size
  MySelection.Font.Name = "Courier New"
  MySelection.Font.Size = 10

'Loop through words that should be blue
  For x = LBound(BlueArray) To UBound(BlueArray)

  Set MySelection = Selection.Range
  Set MySelection_Limit = MySelection.Duplicate

  With MySelection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = BlueArray(x)
    .Replacement.Text = BlueArray(x)
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Replacement.Font.Color = wdColorDarkBlue

    While .Execute
      If MySelection.InRange(MySelection_Limit) Then
        MySelection.Font.Color = wdColorDarkBlue
        MySelection.Collapse wdCollapseEnd
      End If
    Wend
  End With
    
Next x

'Look for a Quote and changes the rest of that line's font color to Green
  With Selection.Find
    .ClearFormatting
    .Text = "'[!^13""""]@[^13]"
    .Replacement.ClearFormatting
    .Replacement.Text = ""
    .Replacement.Font.Color = wdColorGreen
    .Format = True
    .Forward = True
    .Wrap = wdFindStop
    .MatchCase = False
    .MatchWholeWord = False
    .MatchAllWordForms = False
    .MatchSoundsLike = False
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
End Sub

Using VBA Code Found On The Internet

Now that you’ve found some VBA code that could potentially solve your Excel automation problem, what do you do with it? If you don’t necessarily want to learn how to code VBA and are just looking for the fastest way to implement this code into your spreadsheet, I wrote an article (with video) that explains how to get the VBA code you’ve found running on your spreadsheet.

Getting Started Automating Excel

Are you new to VBA and not sure where to begin? Check out my quickstart guide to learning VBA. This article won’t overwhelm you with fancy coding jargon, as it provides you with a simplistic and straightforward approach to the basic things I wish I knew when trying to teach myself how to automate tasks in Excel with VBA Macros.

Also, if you haven’t checked out Excel’s latest automation feature called Power Query, I have put together a beginner’s guide for automating with Excel’s Power Query feature as well! This little-known built-in Excel feature allows you to merge and clean data automatically with little to no coding!

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to get quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee that 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Keep Learning

Chris Newman

Chris Newman

Chris is a finance professional and Excel MVP recognized by Microsoft since 2016. With his expertise, he founded TheSpreadsheetGuru blog to help fellow Excel users, where he shares his vast creative solutions & expertise. In addition, he has developed over 7 widely-used Excel Add-ins that have been embraced by individuals and companies worldwide.