Find And Replace All With VBA In PowerPoint

What This VBA Code Does

This post is a follow-up article to Find And Replace With Excel VBA. The following macro code snippets will show you different variations of how to perform find and replace automation with VBA in Microsoft PowerPoint.

There are a couple of things that confuse people while converting your mindset from an Excel find/replace to a PowerPoint find/replace. Here are the two things you need to understand:

• You cannot just search the entire slide, your VBA code has to loop through every object (or shape) on the slide one by one.

• Each Find/Replace is done individually. The following macros will continue to trim the shape text down until it cannot find any more instances of the “find” word.

  • For example, if you are changing “cat” to “dog” in the sentence “I ran to the cat & pet the cat“. The first find replace would analyze the entire sentence and change it to “I ran to the dog & pet the cat“. Next, the code would trim down the sentence and search “ & pet the cat” for any more instances of “cat” (and so on…).  Are you confused yet?

Find And Replace All

This VBA macro will perform a standard find and replace for one word of your choosing.

Sub FindReplaceAll()
'PURPOSE: Find & Replace text/values throughout entire PowerPoint presentation
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim sld As Slide
Dim shp As Shape
Dim ShpTxt As TextRange
Dim TmpTxt As TextRange
Dim FindWord As Variant
Dim ReplaceWord As Variant

FindWord = "United States"
ReplaceWord = "USA"

'Loop through each slide in Presentation
  For Each sld In ActivePresentation.Slides
    
    For Each shp In sld.Shapes
      'Store shape text into a variable
        Set ShpTxt = shp.TextFrame.TextRange
      
      'Ensure There is Text To Search Through
        If ShpTxt <> "" Then
  
          'Store text into a variable
            Set ShpTxt = shp.TextFrame.TextRange
          
          'Find First Instance of "Find" word (if exists)
            Set TmpTxt = ShpTxt.Replace( _
             FindWhat:=FindWord, _
             Replacewhat:=ReplaceWord, _
             WholeWords:=True)
      
          'Find Any Additional instances of "Find" word (if exists)
            Do While Not TmpTxt Is Nothing
              Set ShpTxt = ShpTxt.Characters(TmpTxt.Start + TmpTxt.Length, ShpTxt.Length)
              
              Set TmpTxt = ShpTxt.Replace( _
               FindWhat:=FindWord, _
               Replacewhat:=ReplaceWord, _
               WholeWords:=True)
            Loop
          
        End If
        
    Next shp
      
  Next sld

End Sub

Find And Replace All (For A List Of Words)

This VBA macro will perform multiple iterations of find and replace for a list of word combinations.

Sub Multi_FindReplace()
'PURPOSE: Find & Replace a list of text/values throughout entire PowerPoint presentation
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim sld As Slide
Dim shp As Shape
Dim ShpTxt As TextRange
Dim TmpTxt As TextRange
Dim FindList As Variant
Dim ReplaceList As Variant
Dim x As Long

FindList = Array("Canada", "United States", "Mexico")
ReplaceList = Array("CAN", "USA", "MEX")

'Loop through each slide in Presentation
  For Each sld In ActivePresentation.Slides
    
    For Each shp In sld.Shapes
      'Store shape text into a variable
        Set ShpTxt = shp.TextFrame.TextRange
      
      'Ensure There is Text To Search Through
        If ShpTxt <> "" Then
          For x = LBound(FindList) To UBound(FindList)
            
            'Store text into a variable
              Set ShpTxt = shp.TextFrame.TextRange
            
            'Find First Instance of "Find" word (if exists)
              Set TmpTxt = ShpTxt.Replace( _
               FindWhat:=FindList(x), _
               Replacewhat:=ReplaceList(x), _
               WholeWords:=True)
        
            'Find Any Additional instances of "Find" word (if exists)
              Do While Not TmpTxt Is Nothing
                Set ShpTxt = ShpTxt.Characters(TmpTxt.Start + TmpTxt.Length, ShpTxt.Length)
                Set TmpTxt = ShpTxt.Replace( _
                 FindWhat:=FindList(x), _
                 Replacewhat:=ReplaceList(x), _
                 WholeWords:=True)
              Loop
              
          Next x
          
        End If
        
    Next shp
      
  Next sld

End Sub

Using VBA Code Found On The Internet

Now that you’ve found some VBA code that could potentially solve your Excel automation problem, what do you do with it? If you don’t necessarily want to learn how to code VBA and are just looking for the fastest way to implement this code into your spreadsheet, I wrote an article (with video) that explains how to get the VBA code you’ve found running on your spreadsheet.

Getting Started Automating Excel

Are you new to VBA and not sure where to begin? Check out my quickstart guide to learning VBA. This article won’t overwhelm you with fancy coding jargon, as it provides you with a simplistic and straightforward approach to the basic things I wish I knew when trying to teach myself how to automate tasks in Excel with VBA Macros.

Also, if you haven’t checked out Excel’s latest automation feature called Power Query, I have put together a beginner’s guide for automating with Excel’s Power Query feature as well! This little-known built-in Excel feature allows you to merge and clean data automatically with little to no coding!

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it’s impossible to account for every particular need one might have. That’s why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to get quick answers to complex problems in Excel, PowerPoint, VBA, you name it! 

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee that 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don’t have time to fit everyone’s questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Hidden Hacks For VBA Macro Coding

After 10+ years of creating macros and developing add-ins, I've compiled all the hacks I wish I had known years ago!

Learn These Hacks Now For Free!

Keep Learning

Explore more →

Find And Break All External Links In Excel File [Guide 2022]

How To Break External Links So you're on a mission to break/remove external links from your Excel workbook, huh? Seems...

Classified Data: Find All Numbers And Replace Them With X’s In Text

Recently I found myself in a situation where another company wanted to see the formatting of numerous reports and presentations...

Find and Replace All With Excel VBA

What This VBA Code Does These VBA macros will show you various ways to find and replace all for any...

Chris Newman

Chris is a finance professional and Excel MVP recognized by Microsoft since 2016. With his expertise, he founded TheSpreadsheetGuru blog to help fellow Excel users, where he shares his vast creative solutions & expertise. In addition, he has developed over 7 widely-used Excel Add-ins that have been embraced by individuals and companies worldwide.