×

VBA To Change Text Case Within A Selection Of Cells

By Chris Newman •  Updated: 12/08/17 •  5 min read
VBA code snippet to change text case within a selection of cells

What This VBA Code Does

The following VBA macro code is something I use all the time to manipulate the look of my report headings. The VBA code mimics a feature that is found in PowerPoint and Word but unfortunately was left out of the Excel Application.

Essentially the macro will loop through applying 3 different case types to your selected cell text. Just keep re-running the macro until you get your desired case.

The case types that can be applied are:

  • Uppercase
  • Lowercase
  • Proper Case

VBA Code (Method 1):

Excel MVP Rick Rothstein stopped by this article and provided a great condensed solution in the comments section. Here is the VBA solution he provided to toggle between Uppercase, Lowercase, and Proper Case:

Sub ToggleTextCase()
'PURPOSE: Toggle selected cell text values between Upper, Lower, & Proper cases
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault (Rick Rothstein)

Dim Cell As Range

For Each Cell In Selection.SpecialCells(xlConstants)
  If Cell.Value Like "[A-Z][A-Z]*" Then
    Cell.Value = LCase(Cell.Value) 'Lowercase
  ElseIf Cell.Value Like "[a-z]*" Then
    Cell.Value = Application.Proper(Cell.Value) 'Propercase
  Else
    Cell.Value = UCase(Cell.Value) 'Uppercase
  End If
Next

End Sub

VBA Code (Method 2):

The following code is my creation which while longer, might be a bit easier to follow depending on your VBA coding skill level.

Sub ToggleTextCase()
'PURPOSE: Toggle selected cell text values between Upper, Lower, & Proper cases
'SOURCE: www.TheSpreadsheetGuru.com/the-code-vault

Dim FirstCellValue As String
Dim rng As Range
Dim cell As Range

'Optimize Code
  Application.ScreenUpdating = False

'Was a Range Selected? (Error Handling)
  If TypeName(Selection) <> "Range" Then
    MsgBox "No cell range was selected!", vbCritical, "No Range Selected"
    Exit Sub
  End If

'Remove cells with formulas or cells that are hidden from selection
  On Error Resume Next
    If Selection.Cells.Count > 1 Then
      Set rng = Selection.SpecialCells(xlCellTypeVisible)
      Set rng = rng.SpecialCells(xlConstants)
    Else
      Set rng = ActiveCell
    End If

'Store Current Case Structure of first cell in selection
  FirstCellValue = rng.Cells(1, 1).Value
  
'Apply Case Change (based on first cell's current case structure)
  If FirstCellValue = LCase(FirstCellValue) Then
    'If Lowercased, make Propercased
      For Each cell In rng.Cells
        cell.Value = Application.WorksheetFunction.Proper(cell.Value)
      Next cell
    
  ElseIf FirstCellValue = UCase(FirstCellValue) Then
    'If Uppercased, make Lowercased
      For Each cell In rng.Cells
        cell.Value = LCase(cell.Value)
      Next cell
    
  Else
    'If Propercased, make Uppercased
      For Each cell In rng.Cells
        cell.Value = UCase(cell.Value)
      Next cell
    
  End If

End Sub

Using VBA Code Found On The Internet

Now that you’ve found some VBA code that could potentially solve your Excel automation problem, what do you do with it? If you don’t necessarily want to learn how to code VBA and are just looking for the fastest way to implement this code into your spreadsheet, I wrote an article (with video) that explains how to get the VBA code you’ve found running on your spreadsheet.

Getting Started Automating Excel

Are you new to VBA and not sure where to begin? Check out my quickstart guide to learning VBA. This article won’t overwhelm you with fancy coding jargon, as it provides you with a simplistic and straightforward approach to the basic things I wish I knew when trying to teach myself how to automate tasks in Excel with VBA Macros.

Also, if you haven’t checked out Excel’s latest automation feature called Power Query, I have put together a beginner’s guide for automating with Excel’s Power Query feature as well! This little-known built-in Excel feature allows you to merge and clean data automatically with little to no coding!

How Do I Modify This To Fit My Specific Needs?

Chances are this post did not give you the exact answer you were looking for. We all have different situations and it's impossible to account for every particular need one might have. That's why I want to share with you: My Guide to Getting the Solution to your Problems FAST! In this article, I explain the best strategies I have come up with over the years to get quick answers to complex problems in Excel, PowerPoint, VBA, you name it

I highly recommend that you check this guide out before asking me or anyone else in the comments section to solve your specific problem. I can guarantee that 9 times out of 10, one of my strategies will get you the answer(s) you are needing faster than it will take me to get back to you with a possible solution. I try my best to help everyone out, but sometimes I don't have time to fit everyone's questions in (there never seem to be quite enough hours in the day!).

I wish you the best of luck and I hope this tutorial gets you heading in the right direction!

Keep Learning

Chris Newman

Chris Newman

Chris is a finance professional and Excel MVP recognized by Microsoft since 2016. With his expertise, he founded TheSpreadsheetGuru blog to help fellow Excel users, where he shares his vast creative solutions & expertise. In addition, he has developed over 7 widely-used Excel Add-ins that have been embraced by individuals and companies worldwide.